plugins {
    id "com.android.application"
}

// Signing key lives outside the repo (see BUILDING.md). keystore.properties provides
// storeFile, storePassword, keyAlias, keyPassword.
def keystoreProps = new Properties()
def keystoreFile = rootProject.file("keystore.properties")
if (keystoreFile.exists()) keystoreFile.withInputStream { keystoreProps.load(it) }

android {
    namespace "com.dayline.photos"
    compileSdk 35

    defaultConfig {
        applicationId "com.dayline.photos"
        minSdk 26
        targetSdk 35
        versionCode 1
        versionName "1.0"
        buildConfigField "String", "DEFAULT_URL", "\"http://192.168.86.100:8340/photo\""
    }

    buildFeatures {
        buildConfig true
    }

    signingConfigs {
        release {
            if (keystoreProps["storeFile"]) {
                storeFile file(keystoreProps["storeFile"])
                storePassword keystoreProps["storePassword"]
                keyAlias keystoreProps["keyAlias"]
                keyPassword keystoreProps["keyPassword"]
            }
        }
    }

    buildTypes {
        release {
            minifyEnabled false
            // debuggable so `adb shell run-as com.dayline.photos` can write files/base_url,
            // the same provisioning model as the dashboard app.
            debuggable true
            signingConfig signingConfigs.release
        }
    }

    lint {
        abortOnError false
        checkReleaseBuilds false
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_17
        targetCompatibility JavaVersion.VERSION_17
    }
}